#!/usr/bin/perl -w
################################
# Test various variables and subroutines in MarlboroCollegeSchedule.cgi
# $Id: test.pl,v 1.4 2002/04/12 09:01:20 msie Exp $
########################

use Test::Simple tests => 9;

#--------------------------------------------------------
# 1. -- Does it compile ?
my $compiles = eval " require 'MarlboroClassSchedule.cgi'";
ok($compiles, "MarlboroClassSchedule.cgi compiles" );

package MarlboroClassSchedule;

# An alias for the Test::Simple::ok() subroutine.
# I need this because I'm now working inside another package namespace.
sub OK {
  my ($test, $name) = @_;
  return main::ok($test, $name);
}

#--------------------------------------------------------
# 2. -- Does the last modified date look like it's a time?
our $lastmodified; # This avoids warning that lastmodified is mentioned 1nce.
OK( $lastmodified =~ /\d{4}$/ ,	"modification date ends in dddd");

#--------------------------------------------------------
# 3. -- Can we store some data and read it from the file system ?
$blockdata = { one => 1, two => 2 };
writeData();
$blockdata = {};
readData();
OK( $blockdata->{one} == 1 ,	"can read and write to datafile" );

# -- live tests --
my $defaultURL = "http://bob.marlboro.edu/~msie/2002/ipl/perl/lectures/apr12/RegistrarSchedule/deploy/MarlboroClassSchedule.cgi";
print "Url for live tests? [$defaultURL] ";
chomp(my $url = <>);
$url = $url || $defaultURL;

#--------------------------------------------------------
# 4. -- Can we fetch the webpage ?
#       (See lwp-cookbook from libwww-perl)
use LWP::UserAgent;
my $ua  = LWP::UserAgent->new;
my $req = HTTP::Request->new( GET => $url );
$req->header("Accept" => "text/html");
my $result = $ua->request($req);
my $status = $result->status_line;
OK( $result->is_success, "fetching web page, status is $status ");

#--------------------------------------------------------
# 5. -- Does the webpage have an "Edit 11:30" link?
my $pagelink = '<a href="MarlboroClassSchedule.cgi\?edit=mon1130">Edit</a>';
OK( $result->content =~ /$pagelink/, "has edit=mon1130 link ");

#--------------------------------------------------------
# 6. -- Can we fetch the edit 11:30 page?
$req = HTTP::Request->new( GET => $url."?edit=mon1130" );
$req->header("Accept" => "text/html");
$result = $ua->request($req);
$status = $result->status_line;
OK( $result->is_success, "fetching edit page, status is $status ");

#--------------------------------------------------------
# 7. -- And does it have the text form on it?
$pagelink = '<textarea name="text" rows="20" cols="40" wrap="soft">';
OK( $result->content =~ /$pagelink/, "has <textarea...> ");

#--------------------------------------------------------
# 8. -- Can we post some new stuff ?
my $newtext = "this text is from the test";
#$req = HTTP::Request->new( POST => $url );
#my $escaped = CGI::escape($newtext);
#$req->content_type('application/x-www-form-urlencoded');
#$req->content('whichBlock=mon1130&text=$escaped&saveChanges=1');
use HTTP::Request::Common qw(POST);
$req = POST $url, [ whichBlock  => "mon1130", 
		    text	=> $newtext,
		    saveChanges => "Save Changes",
		  ];
#print "request is " . $req->as_text . "'\n";
$result = $ua->request($req);
$status = $result->status_line;
OK( $result->is_success, "posting altered text, status is $status ");

#--------------------------------------------------------
# 9. -- And are the changes we made actually in the new page?
#print " content: " . $result->content . "\n";
my $match = ($result->content =~ /$newtext/);
OK( $match , "modified schedule does have new text "  );


print "Finished tests.\n";